FilesOpen

10 REMark FilesOpen V0.02
11 :
12 REMark  Test harness
13 dv$ = 'ram1_':  REMark Medium to test
14 :
15 c1 = FOP_OVER(dv$ & "test1xyz."): PRINT 'test1'! c1: ERT c1
16 c2 = FOP_OVER(dv$ & "test2xyz."): PRINT 'test2'! c2: ERT c2
17 PRINT 'Files open on'! dv$! '='! FilesOpen%(dv$)
18 CLOSE#c2: DELETE dv$ & 'test2xyz.'
19 PRINT 'Files open on'! dv$! '='! FilesOpen%(dv$)
20 CLOSE#c1: DELETE dv$ & 'test1xyz.'
21 PRINT 'Files open on'! dv$! '='! FilesOpen%(dv$)
22 :
23 :
100 REMark + ------------------------------------------------------------------------ +
101 REMark |<                              Files Open                                >|
102 REMark + ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~ +
103 REMark |                  Show number of files open on a medium                   |
104 REMark |                                                                          |
105 REMark | SMSQ/E, SBASIC                                                           |
106 REMark + ------------------------------------------------------------------------ +
107 REMark | V0.01, pjw, November 13th 2017                                           |
108 REMark | V0.02, pjw, March 26th 2019, simplified                                  |
109 REMark + ------------------------------------------------------------------------ +
110 :
111 DEFine FuNction FilesOpen%(drv$)
112 LOCal i, p, l%, m$(10)
113 m$ = DMEDIUM_NAME$(\ drv$): l% = LEN(m$)
114 :
115 FOR i = 0 TO 15 * 4 STEP 4
116  p = PEEK_L(!! $100 + i): IF p = 0: EXIT i
117  IF m$ = PEEK$(p + 22, l%): RETurn PEEK(p + $22)
118 END FOR i
119 RETurn -7
120 END DEFine FilesOpen%
121 :
122 :